есть запрос:
   Запрос.Текст =
   "ВЫБРАТЬ
   |    ОсновнойОбороты.Счет,
   |    ОсновнойОбороты.Субконто1,
   |    ОсновнойОбороты.Субконто2,
   |    ОсновнойОбороты.Субконто3,
   |    ОсновнойОбороты.Регистратор,
   |    ОсновнойОбороты.НомерСтроки,
   |    ОсновнойОбороты.СуммаОборот,
   |    ОсновнойОбороты.СуммаОборотДт,
   |    ОсновнойОбороты.СуммаОборотКт,
   |    ОсновнойОбороты.Организация,
   |    ОсновнойОбороты.ВидКапитала,
   |    ОсновнойОбороты.План,
   |    ОсновнойОбороты.КоличествоОборотДт,
   |    ОсновнойОбороты.КоличествоОборотКт,
   |    ОсновнойОбороты.ВалютнаяСуммаОборотДт,
   |    ОсновнойОбороты.ВалютнаяСуммаОборотКт
   |
   |ИЗ
   |    РегистрБухгалтерии.Основной.Обороты(
   |            "+?(ЗначениеЗаполнено(НачПериода),"&НачДата","")+",
   |            "+?(ЗначениеЗаполнено(КонПериода),"&КонДата","")+",
   |            Запись,
   |            Счет = &Счет,
   |            ,
   |            "+?(ЗначениеЗаполнено(ЮрЛицо),"Организация = &Организация","")+ УсловиеПоСубконто +"
   |            ,
   |            ) КАК ОсновнойОбороты";

как выбрать движения только с типом регистратора "Операция". Какой условие нужно добавить в запрос

Регистратор ССЫЛКА Документ.ОперацияБух

куда это вставить?

(2) ГДЕ
  ОсновнойОбороты.Регистратор ССЫЛКА Документ.ОперацияБух

спасибо!

На будущее, писать стоит так:

ТекстЗапроса =
"ВЫБРАТЬ * ИЗ РегистрБухгалтерии.Основной.Обороты(&НачДата, &КонДата, Запись,Счет = &Счет, Организация = &Организация,) КАК ОсновнойОбороты";

Если Не ЗначениеЗаполнено(НачПериода) Тогда
   ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&НачДата", "");
Иначе
   Запрос.УстановитьПараметр("НачДата", НачПериода);
КонецЕсли;
Если Не ЗначениеЗаполнено(КонПериода) Тогда
   ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&КонДата", "");
Иначе
   Запрос.УстановитьПараметр("КонДата", КонПериода);
КонецЕсли;
Если Не ЗначениеЗаполнено(ЮрЛицо) Тогда
   ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "Организация = &Организация", "");
Иначе
   Запрос.УстановитьПараметр("Организация", ЮрЛицо);
КонецЕсли;

Запрос.Текст = ТекстЗапроса;

Так запрос будет открываться конструктором. А "кусковой" запрос ужасно сложен для восприятия и редактировать его можно либо приводя в первоначальный вид (а потом все "вставки" назад возвращать), либо чисто вручную править текст запроса.