Здравствуйте, подскажите пожалуйста, как мне перебрать табличные части всех документов и если встречается номенклатура помеченная на удаление в этой табличной части, то удалить ее ?

Вот так выбираю все документы:

МассивДокументов=Метаданные.Документы;
    Для каждого СтрМас Из МассивДокументов Цикл
        ДокТип=СтрМас.Имя;
        Запрос = Новый Запрос;
        Запрос.Текст =
        "ВЫБРАТЬ
        |    "+ДокТип+".Ссылка
        |ИЗ
        |    Документ."+ДокТип+" КАК "+ДокТип;
        Результат = Запрос.Выполнить();
        ВыборкаДетальныеЗаписи = Результат.Выбрать();
        Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
            Сообщить(" "+ВыборкаДетальныеЗаписи.Ссылка);
        КонецЦикла;
    КонецЦикла;

Как мне выбрать только те документы в которых есть номенклатура помеченная на удаление и удалить ее?

>>Как мне выбрать только те документы в которых есть номенклатура помеченная на удаление и удалить ее?

кури НайтиПомеченныеНаУдаление + НайтиПоСсылкам

а как выбрать табличную часть? они же по разному называются для всех документов?

Можешь просто сделать удаление помеченных номенклатур, контроль сам скажет где они есть, в т.ч. и документы какие

а как мне потом удалить номенклатуру из этих документов? их же там много? в ручную это очень долго

Запрос не к документам, а к табличным частям (не помню ни одного документа с номенклатурой в шапке). Есть общая процедура проверки, есть ли указанный реквизит в объекте. Дальше совсем просто
| ГДЕ ...Номенклатура.ПометкаУдаления

Вот от удаления документов дошли до удаления номенклатуры из документов. Следующая тема будет, видимо, "как удалить из движений" либо "после перепроведения документов изменились остатки"

(4) есть консоль запросов с функцией обработки полученного результата (у меня только под обычное приложение)

spu79, подскажите пожалуйста что за процедура проверки?

Несколько запросов в цикле, который формируется по метаданным табличных частей. Заодно можно отбросить все те типизированные ТЧ в которых номенклатуры в принципе быть не может.

устанешь запрос сочинять, я реально. Найди просто все помеченный на удалени, отфильтруй оттуда только номенклатуру и НайтиПоссылкам(массив номенклатур)

как сделать запрос к табличным частям всех документов?

что в лоб, что по лбу. Неверный путь выбрали изначально. Ну как хотите

(0) Eeelena , удаление  помеченных объектов - это есть во всех конфигурациях. Полный интерфейс - Операции - Удаление помеченных объектов. Чем оно тебя не устраивает?

мне нужно не просто удалит номенклатуру, а именно из документов

(14) Там есть возможность выбрать только номенклатуру и удалить только из документов.

(15) нет там возможности удалить из документов строки с номенклатурой. Или у вас продвинутая версия?

(14) удалить номенклатуру или строки с номенклатурой?

простите, строки номенклатуры из документа

(18) а как насчет (6)????

(18) А с суммой документа что будет при этом? Был документ на сумму 100 руб и 10 позиций. Вы убираете строку №7 на сумму 15 руб. Сумма документа меняется. И чем вам лучше?

дак без разницы что с суммой нужно удалить строку

(16) Упс. Сорри, был не прав. "Погорячился"(с)

(8) МетаданныеОбъекта = Объект.Ссылка.Метаданные();
МетаданныеОбъекта.Реквизиты.Найти(Реквизит) <> Неопределено
проверка на наличие реквизита.
пример из: Общий модуль, ОбщегоНазначенияУТ. конф УТ 11.1.2.8
метод найти (раздел Работа с объектами метаданных)

Найти (Find)
Синтаксис:

Найти(<ИмяПоля>)
Параметры:

<ИмяПоля> (обязательный)

Тип: Строка.
Имя искомого поля ввода по строке.
Возвращаемое значение:

Тип: Поле; Неопределено.
Если не найден, возвращается Неопределено.
Описание:

Осуществляет поиск поле ввода по строке по его имени.

Доступность:

Сервер, толстый клиент, внешнее соединение.

Сорри, имхо методически неверные решения. Сейчас попробую набросать болванку алгоритма.

буду очень признательна

Вот такая методика поиска и отбора подходит? Дальше есть смысл писать?

    ТипСсылокПомеченныхНаУдаление = Тип("СправочникСсылка.Номенклатура");
    
    МассивПомеченныхНаУдаление = Новый Массив();
    Для Каждого СсылкаПомеченнаяНаУдаление Из НайтиПомеченныеНаУдаление() Цикл
        Если ТипЗнч(СсылкаПомеченнаяНаУдаление) = ТипСсылокПомеченныхНаУдаление Тогда
            МассивПомеченныхНаУдаление.Добавить(СсылкаПомеченнаяНаУдаление);
        КонецЕсли;
    КонецЦикла;
    
    Для Каждого НайденнаяСсылка Из НайтиПоСсылкам(МассивПомеченныхНаУдаление) Цикл
        Если Документы.ТипВсеСсылки().СодержитТип(ТипЗнч(НайденнаяСсылка.Данные)) Тогда
            Сообщить("Документ """ + НайденнаяСсылка.Данные + """, содержит ссылку на """ + НайденнаяСсылка.Ссылка + """");
        КонецЕсли;
    КонецЦикла;

спасибо большое, вы очень помогли)

еще подскажите пожалуйста как мне удалить эту найденную номенклатуру?

Наберись терпения, сейчас допишу (надо ведь ещё базу найти,которую не жалко:)

очень жду) только номенклатуру нужно удалить именно из документа

(30) сейчас сравни (1) и (26), это одно и тоже

Вот, разродился гадким утёнком. Алгоритм, имхо, - не фонтан. Вы спросите "Почему?".

Потому что мне не понятна позиция автора в случае, когда в табличной части присутствуют несколько колонок с типом справочника Номенклатура. Ну, например, в таблице документа есть колонки "Материал" и "Продукция". И что в таком случае проверять будем? Непонятно :(

ТипСсылокПомеченныхНаУдаление = Тип("СправочникСсылка.Номенклатура");
    
    МассивПомеченныхНаУдаление = Новый Массив();
    Для Каждого СсылкаПомеченнаяНаУдаление Из НайтиПомеченныеНаУдаление() Цикл
        Если ТипЗнч(СсылкаПомеченнаяНаУдаление) = ТипСсылокПомеченныхНаУдаление Тогда
            МассивПомеченныхНаУдаление.Добавить(СсылкаПомеченнаяНаУдаление);
        КонецЕсли;
    КонецЦикла;
    
    Для Каждого НайденнаяСсылка Из НайтиПоСсылкам(МассивПомеченныхНаУдаление) Цикл
        Если Документы.ТипВсеСсылки().СодержитТип(ТипЗнч(НайденнаяСсылка.Данные)) Тогда
            НадоЗаписать = Ложь;
            Объект = НайденнаяСсылка.Данные.ПолучитьОбъект();
            Для Каждого МетаданныеТабличнаяЧасть Из Объект.Метаданные().ТабличныеЧасти Цикл
                ТабличнаяЧастьОбъекта = Объект[МетаданныеТабличнаяЧасть.Имя];
                Пока Истина Цикл
                    СтрокаТабличнойЧасти = ТабличнаяЧастьОбъекта.Найти(НайденнаяСсылка.Ссылка);
                    Если СтрокаТабличнойЧасти = Неопределено Тогда
                        Прервать;
                    Иначе
                        Сообщить("Документ """ + НайденнаяСсылка.Данные + """, строка № " + СтрокаТабличнойЧасти.НомерСтроки + " содержит ссылку на """ + НайденнаяСсылка.Ссылка + """");
                        ТабличнаяЧастьОбъекта.Удалить(СтрокаТабличнойЧасти);
                        НадоЗаписать = Истина;
                    КонецЕсли;
                КонецЦикла;
            КонецЦикла;
            Если НадоЗаписать Тогда
                Если Объект.Проведен Тогда
                    Объект.Записать(РежимЗаписиДокумента.Проведение);
                Иначе
                    Объект.Записать(РежимЗаписиДокумента.Запись);
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
    Возврат;

Serg_1960, спасибо большое)