В БП 2.0   была хорошая функция :
БухгалтерскийУчет.ПолучитьСведенияОСчете()

что в взамен ее применить в БП 3.0 ?

а что в ней было? есть мнение, что она была лишней

Вот такая замечательная функция :
Я вызывал ее по OLE :(

// Эта функция возвращает информацию о счете из переданного соответсвия
// Если в соответствии не найдена информация о счете - она подготавливается и
// помещается в соответсвие
// Применяется для работы с формами в которых активно требуется получать
// информацию о счетах, например, при выводе строки табличного поля
//
// Параметры:      
//    СведенияОСчетах - соответсвие у которого в качестве ключа - ПланСчетовСсылка, а
//                    в качестве значения - структура из 4-х элементов
//                      КоличествоСубконто - число
//                    ТипСубконто1 - описание типа
//                    ТипСубконто2 - описание типа
//                    ТипСубконто3 - описание типа
//                      ВидСубконто1Представление - представление вида субконто
//                      ВидСубконто2Представление - представление вида субконто
//                      ВидСубконто3Представление - представление вида субконто
//
//    Счет - ПланСчетовСсылка
//
// Возвращаемое значение:
//  Описанная выше структура
//
Функция ПолучитьСведенияОСчете(СведенияОСчетах, Счет) Экспорт

    СведенияОСчете = СведенияОСчетах[Счет];

    Если СведенияОСчете = Неопределено Тогда

        СведенияОСчете = Новый Структура("КоличествоСубконто, ВидСубконто1, ВидСубконто2, ВидСубконто3, ТипСубконто1, ТипСубконто2, ТипСубконто3, ВидСубконто1Представление, ВидСубконто2Представление, ВидСубконто3Представление");

        СведенияОСчете.КоличествоСубконто = Счет.ВидыСубконто.Количество();

        Если СведенияОСчете.КоличествоСубконто > 0 Тогда

            ВидСубконто = Счет.ВидыСубконто[0].ВидСубконто;

            СведенияОСчете.ВидСубконто1              = ВидСубконто;
            СведенияОСчете.ТипСубконто1              = ВидСубконто.ТипЗначения;
            СведенияОСчете.ВидСубконто1Представление = ВидСубконто.Наименование;

        КонецЕсли;

        Если СведенияОСчете.КоличествоСубконто > 1 Тогда

            ВидСубконто = Счет.ВидыСубконто[1].ВидСубконто;

            СведенияОСчете.ВидСубконто2              = ВидСубконто;
            СведенияОСчете.ТипСубконто2              = ВидСубконто.ТипЗначения;
            СведенияОСчете.ВидСубконто2Представление = ВидСубконто.Наименование;

        КонецЕсли;

        Если СведенияОСчете.КоличествоСубконто > 2 Тогда

            ВидСубконто = Счет.ВидыСубконто[2].ВидСубконто;

            СведенияОСчете.ВидСубконто3              = ВидСубконто;
            СведенияОСчете.ТипСубконто3              = ВидСубконто.ТипЗначения;
            СведенияОСчете.ВидСубконто3Представление = ВидСубконто.Наименование;

        КонецЕсли;

        СведенияОСчетах[Счет] = СведенияОСчете;

    КонецЕсли;

    Возврат СведенияОСчете;

КонецФункции  // ПолучитьСведенияОСчете

(2) БухгалтерскийУчетВызовСервераПовтИсп.ПолучитьСвойстваСчета(Счет)

только через внешнее соединение этот модуль недоступен.