Привет, а в типовой утп для украины 1.2 есть возможность временного резервирования товаров?
ну, типа зарезервировал, если после 3 дней еще в резерве тогда удаляем 3 дневные резервы с резерва в свободные остатки?

В типовой УТ 10.3 можно было закрывать заказы покупателей по просроченным резервам.

(1) да, спасибо, это и буду использовать

что то вышло типа такое

    ЗаписьЖурналаРегистрации("УдалениеУстаревшихРезервов",УровеньЖурналаРегистрации.Информация,,,"Старт",);
    КоличествоДнейПросрочки =  2;
    Период_День  = НачалоДня(ТекущаяДата()) -КоличествоДнейПросрочки * 3600 * 24;
    
    Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ТоварыВРезервеНаСкладахОстатки.Склад,
    |    ТоварыВРезервеНаСкладахОстатки.ДокументРезерва,
    |    ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток
    |ИЗ
    |    РегистрНакопления.ТоварыВРезервеНаСкладах.Остатки КАК ТоварыВРезервеНаСкладахОстатки
    |ГДЕ
    |    ТоварыВРезервеНаСкладахОстатки.КоличествоОстаток > 0
    |    И ТоварыВРезервеНаСкладахОстатки.ДокументРезерва.Дата < &День";
    
    Запрос.УстановитьПараметр("День",Период_День);
    
    РезультатЗапроса = Запрос.Выполнить();    
    ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
    
    Если РезультатЗапроса.Пустой() Тогда
        Возврат;
    КонецЕсли;
    
    Док = Документы.ЗакрытиеЗаказовПокупателей.СоздатьДокумент();    
    Док.Дата = ТекущаяДата();
    Док.ВидОперации = Перечисления.ВидыОперацийЗакрытиеЗаказовПокупателей.СнятиеРезервов;
    
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        СтрокаЗаказ = Док.Заказы.Добавить();
        СтрокаЗаказ.ЗаказПокупателя = ВыборкаДетальныеЗаписи.ДокументРезерва;    
    КонецЦикла;
    
    Док.Комментарий = "Создан автоматически закрытия резервов по истечение "+КоличествоДнейПросрочки+" дней";
    
    Попытка
        Док.Записать(РежимЗаписиДокумента.Проведение);
    Исключение
        ЗаписьЖурналаРегистрации("УдалениеУстаревшихРезервов",УровеньЖурналаРегистрации.Ошибка,,,ОписаниеОшибки(),);
    КонецПопытки;
    
    ЗаписьЖурналаРегистрации("УдалениеУстаревшихРезервов",УровеньЖурналаРегистрации.Информация,,,"Финиш",);

может кому то пригодно будет